Hi Guys,
I am trying to find an original working copy of the demo program "Bit Bucket."
The original copy seems to come from a disk from the APPLE CORE GROUP out of San Francisco. A version of this program is now available, but is bundled with some others. The bundled versions come from two different disks. However, the Bit Bucket program on these images does not run correctly.
Bundled Dsk #1 has the title: cple_Animals_Animations_Biorhythm_Bit_Bucket_Echo_6502_Simulator_Sleepy_Time_Star_Wars.dsk
Bundled Dsk #2 (located by Guru Fadden - Thank You) comes from the source shown below:
https://www.apple.asimov.net/images/misc/3d0g_knight_collection/080b%20-%20MicroTyping%20Tutor%20Demos.dsk
Anybody know if APPLE CORE program dsk s exist somewhere in cyber space?
I know, this is a weird request, but then, this is the magic land of Apple II.
Tom K

On Friday, January 12, 2024 at 11:58:05 AM UTC-5, James Hall [VE3MYZ] FN25dj. 73 wrote:
> This works in Clock Signal, with an Apple ][ and 16-sector Drive.
>
> 4 POKE -16368,0: POKE -16298,0: TEXT : CALL -936
> 5 GOSUB 400
> 10 GR : COLOR= 15
> 20 FOR I=1 TO 300: PLOT RND (36)+2, RND (28)+11: NEXT I
> 21 FOR I=1 TO 20
> 22 X= RND (40):Y= RND (40): IF SCRN(X,Y)=0 THEN 22
> 23 PLOT X,Y:Y=Y+1: IF Y>39 THEN 25: IF SCRN(X,Y)#0 THEN 25: GOTO 23
> 25 NEXT I
> 30 Y=0:X=19
> 31 IF SCRN(X,0)#0 THEN 30
> 32 C=8
> 33 IF PEEK (-16384)=155 THEN 390
> 35 HX=X:HY=Y
> 40 IF SCRN(X,Y+1)=0 THEN 100
> 41 FOR Q=1 TO 2
> 45 A= PEEK (-16336)+ PEEK (-16336)
> 46 NEXT Q
> 50 IF X=0 OR X=39 THEN 30
> 60 IF SCRN(X-1,Y)#0 AND SCRN(X+1,Y)#0 THEN 30
> 70 DX=1: IF RND (2)=1 THEN DX=-1
> 75 IF SCRN(X+DX,Y)#0 THEN 70
> 80 GOTO 300
> 100 IF Y=39 THEN 41:Y=Y+1
> 110 COLOR= 0: PLOT HX,HY:HX=X:HY=Y: COLOR= C: PLOT X,Y: GOTO 40
> 300 X=X+DX: COLOR= 0: PLOT HX,HY:HX=X:HY=Y
> 310 COLOR= C: PLOT X,Y
> 311 IF Y=39 THEN 320
> 315 IF SCRN(X,Y+1)=0 THEN 40
> 320 IF X=0 OR X=39 THEN 30
> 330 IF SCRN(X+DX,Y)#0 THEN 30
> 350 GOTO 300
> 390 POKE -16368,0: POKE -16298,0: TEXT : CALL -936: VTAB 10: TAB 10: PRINT "* * * THE END * * *": END
> 400 CALL -936: VTAB 5: PRINT " BIT BUCKET"
> 410 PRINT : PRINT : PRINT " AUTHOR UNKNOWN": PRINT
> 420 PRINT " THIS PROGRAM GENERATES A RANDOM "
> 430 PRINT "MAZE AND THEN FILLS THIS MAZE WITH"
> 440 PRINT "ONE BIT AT A TIME.."
> 450 VTAB 21: PRINT "PRESS 'ESC' TO END"
> 460 PRINT "PRESS THE SPACE BAR TO CONTINUE..."
> 470 IF PEEK (-16384)=155 THEN 390
> 480 IF PEEK (-16384)<>160 THEN 450
> 490 POKE -16368,0: CALL -936: RETURN
> 500 REM
> 510 REM GIVEN TO APPLE CORE OF SAN FRANCISCO FOR USE OF MEMBERS BY AUTHOR....
> 520 REM
> 530 REM LAST MOD. JULY 1979
> 540 REM
> 550 REM ' BIT BUCKET '
> 560 END
>
>
> 73 ve3myz James
Hi James,
Sorry about the slow reply.
Thank you for your help.
In running this working copy, I discovered that this is not the version of Bit Bucket that I was looking for.
The above "Apple Core" version starts with a random maze. The version I was looking for started with a pattern of "pegs." The random falling bits then had a 50 50 chance of choosing a right or left downward path at each "peg". The end result was a randomly generated pyramid - an approximate Gaussian curve.
Sorry about the confusion. Apparently, my sought after version did not come from Apple Core. After a thousand years, my memory was a little foggy about this. It may have come from "Apple Pugetsound Program Library Exchange (A.P.P.L.E.)." I searched the https://www.callapple.org/ website without success in finding "Bit Bucket."
Thanks again for your help.
Tom K.

>>The version I was looking for started with a pattern of "pegs." The random falling bits then had a 50 50 chance of choosing a right or left downward path at each "peg". The end result was a randomly generated pyramid - an approximate Gaussian curve.
> Sorry about the confusion. Apparently, my sought after version did not come from Apple Core. After a thousand years, my memory was a little foggy about this. It may have come from "Apple Pugetsound Program Library Exchange (A.P.P.L.E.)." I searched the https://www.callapple.org/ website without success in finding "Bit Bucket."
> Thanks again for your help.
> Tom K.

Maybe this from "THE MATHEMATICS TEACHER" Nov 1983. If you want the Full Article email me and i will email the Three Pages.

5 GOSUB 5000: HOME
10 HOME :BIAS = .5: POKE 33,40
20 REM ORIGINAL CONCEPT BY
30 REM SIR FRANCIS GALTON
40 REM DESIGN BY
50 REM JOSEPH HILSENRATH
60 REM PROGRAM BY BRUCE FIELD
70 VTAB 5: PRINT "PROGRAM PRODUCES A GALTON QUINCUNX": PRINT : PRINT "TO SIMULATE A NORMAL DISTRIBUTION."
80 PRINT : PRINT "DO YOU WISH TO BIAS THE DISTRIBUTION?": PRINT : INPUT "(Y/N)==>";A$
90 IF A$ = "N" THEN 110
100 PRINT : INPUT "TYPE A NUMBER BETWEEN .3 AND .7==>";BIAS
110 PRINT : INPUT "TYPE A SPEED BETWEEN O-100==>";Z
120 PRINT : PRINT "ENTER A NUMBER BETWEEN 0 AND 100 TO": PRINT : INPUT "SEED THE RANDOM NUMBER GENERATOR==>";SR
130 FOR I = 1 TO SR:R = RND (1): NEXT I: HTAB 30
140 DATA 1,0,4,0,35,45,54,63,4,0
150 REM GENERATE BALL-SHAPE TABLE
160 DIM H(11)
170 POKE 232,0: POKE 233,64
180 FOR I = 16384 TO 16393: READ A: POKE I,A: NEXT I
190 FOR I = 1 TO 11
200 H(I) = 0: NEXT I
210 HGR : HCOLOR= 2: ROT= 8: SCALE= 3
220 HPLOT 50,0 TO 230,0 TO 230,159 TO 50,159 TO 50,0
230 REM SET UP GRID
240 X0 = 140:Y0 = 10
250 FOR I = 1 TO 9 STEP 2
260 X = X0 - 8 * (I - 1)
270 Y = Y0 + 8 * (I - 1)
280 FOR J = 1 TO I: HPLOT X,Y
290 X = X + 16: NEXT J
300 X = X0 - I * 8:Y = Y + 8
310 FOR J = 1 TO I + 1
320 HPLOT X,Y:X = X + 16
330 NEXT J: NEXT I
340 REM DROP BALL
350 DROPS = 1
360 X = X0
370 FOR Y = Y0 TO YO + 80 STEP 8
380 IF Y = Y0 GOTO 400
390 XDRAW 1 AT X,Y - 8:X = X1
400 DRAW 1 AT X,Y
410 R = RND (1):P = ( INT (100 * R)) / 100
420 VTAB 21: HTAB 35: PRINT P
430 IF P < BIAS GOTO 450
440 X1 = X + 8: GOTO 470
450 X1 = X - 8
460 REM ADJUST THIS LOOP TO CHANGE SPEED
470 FOR I = 1 TO 102 - Z: NEXT I
480 S = - 16336: FOR B = 1 TO 4
490 BOUNCE = PEEK (S) - PEEK (S)
500 NEXT B
510 NEXT Y
520 XDRAW 1 AT X,Y - 8
530 I = (X - X0) / 16 + 6
540 H(I) = H(I) + 1
550 Y = 159 - H(I) / 2
560 HPLOT X - 6,Y TO X + 7,Y
570 VTAB 23: HTAB 12: INVERSE : PRINT "THE GALTON QUINCUNX": NORMAL
580 VTAB 21: PRINT "DROPS= "DR;: HTAB I * 3 + 2: PRINT "."
590 VTAB 22: HTAB I * 3 + 2: PRINT H(I);
600 DR = DR + 1
610 IF DROPS < 500 GOTO 360
620 VTAB 24: INPUT "AGAIN? Y OR N: ";R$
630 IF R$ = "Y" THEN CLEAR : GOTO 10
640 HOME :D$ = CHR$ (4): PRINT D$"RUN SYSTEM MENU"
650 END
999 END
5000 TEXT : HOME
5010 GOSUB 5090
5020 RETURN
5040 TEXT : HOME
5050 INVERSE : FOR I = 1 TO 3: VTAB I: FOR J = 1 TO 38: PRINT "*";: NEXT J: PRINT "*": NEXT I
5060 FOR I = 4 TO 21: VTAB I: HTAB 1: PRINT "*";: HTAB 39: PRINT "*": NEXT I
5070 FOR I = 1 TO 38: PRINT "*";: NEXT I: PRINT "*": NORMAL
5080 RETURN
5090 GOSUB 5040
5091 REM -- ARTICLE TITLE
5092 VTAB 5: HTAB 13: PRINT "GALTON QUINCUNX"
5094 VTAB 7: HTAB 18: PRINT "BY"
5099 REM -- AUTHOR'S NAME
5100 VTAB 9: HTAB 3: PRINT "JOSEPH HILSENRATH & BRUCE F. FIELD"
5105 VTAB 14: HTAB 17: PRINT "FROM"
5110 VTAB 16: HTAB 8: PRINT "THE MATHEMATICS TEACHER"
5115 REM ---ENTER VOL. NO.
5120 HTAB 11: PRINT "VOLUME 76 NUMBER 8"
5121 HTAB 11: PRINT "(C) COPYRIGHT 1983"
5150 VTAB 23
5160 GOSUB 5210
5165 REM -- GO TO DESCRIPTION
5166 GOSUB 6000
5170 RETURN
5180 PRINT : VTAB 23
5190 GOSUB 5210: FOR I = 4 TO 21: VTAB I: HTAB 2: FOR J = 2 TO 37: PRINT " ";: NEXT J: PRINT " ": NEXT I
5200 RETURN
5210 VTAB 24: HTAB 7: PRINT "PRESS ANY KEY TO CONTINUE. ";: GET R$
5240 RETURN
6000 GOSUB 5040
6010 VTAB 5: HTAB 3
6015 REM -ENTER SHORT DESCRIPTION
6020 PRINT "PROGRAM TO SIMULATE THE GALTON": HTAB 3: PRINT "QUINCUNX. THE QUINCUNX IS A DEVICE": HTAB 3: PRINT "THAT IS USED TO APPROXIMATE A NORMAL": HTAB 3: PRINT "DISTRIBUTION."
6040 VTAB 16: HTAB 4: PRINT "FOR DETAILS, CONSULT:"
6042 HTAB 8: PRINT "THE MATHEMATICS TEACHER"
6043 HTAB 13: PRINT "NOVEMBER, 1983"
6044 HTAB 15: PRINT "PAGE 571"
6050 GOSUB 5210
6500 RETURN

73 ve3myz James